File:Sehne.svg
Original file (SVG file, nominally 219 × 198 pixels, file size: 28 KB)
Captions
Summary[edit]
DescriptionSehne.svg |
Deutsch: Kreis mit Mittelpunkt und Radius (mit Mittelpunktswinkel und Umfangswinkeln und für die Winkelscheitel ), der durch eine Sehne (rot, gelb hinterlegt) in zwei Kreisbögen (grün) und (schwarz) unterteilt wird.
English: Circle with center and radius (with central angle and inscribed angles and for vertices ), which ist separated into two arcs (green) and (black) by chord (red, highlighted yellow). |
Date | |
Source | Own work |
Author | SweetWood, (based on "Sehne.png") |
Other versions | Sehne.png |
SVG development InfoField | |
Source code InfoField | Asymptote code// created with Asymptote 2.67: The Vector Graphics Language
// using online-editor: http://asymptote.ualberta.ca/
import graph;
size(175);
/* given values */
pair M = (0,0); // center
real r = 1; // radius
real angleA = 100; // angle of point A [°]
real angleB = 350; // angle of point B [°]
real angleC1 = 20; // angle of point C1 [°]
real angleC2 = 50; // angle of point C2 [°]
real angleC3 = 185; // angle of point C3 [°]
real angleC4 = 225; // angle of point C4 [°]
// returns a pair representing a point on a circle with center c and radius r at angle degrees
pair pointOnCircle(pair c = (0,0), real r = 1, real degrees = 0) {
return c + scale(r) * dir(degrees);
}
// returns an arc with radius r centered at c from pair z1 to z2
path arc(pair c, pair z1, pair z2, real r, bool direction=CCW) {
return arc(c, r, degrees(z1 - c), degrees(z2 - c), direction);
}
// returns an arc with radius r centered at c from pair z1 to z2
//path Arc(pair c, pair z1, pair z2, real r, bool direction=CCW, int n=nCircle) {
// return Arc(c, r, degrees(z1 - c), degrees(z2 - c), direction, n);
//}
pair A = pointOnCircle(M, r, angleA); // calculate position of point A
pair B = pointOnCircle(M, r, angleB); // calculate position of point B
pair C1 = pointOnCircle(M, r, angleC1); // calculate position of point C1
pair C2 = pointOnCircle(M, r, angleC2); // calculate position of point C2
pair C3 = pointOnCircle(M, r, angleC3); // calculate position of point C3
pair C4 = pointOnCircle(M, r, angleC4); // calculate position of point C4
draw(arc(M, r, angleA, angleB, CW), heavygreen); // draw arc b1 from A to B
draw(arc(M, r, angleA, angleB, CCW)); // draw arc b2 from A to B
draw(A--B, yellow+linewidth(1.5)); // draw background of chord
draw("$s$", A--B, red); // draw chord s from A to B
label("$k$", pointOnCircle(M, r, -45), dir(-45)); // label circle
// draw radius and angle at M
draw("$r$", M--A, heavygreen);
draw("$r$", B--M, heavygreen);
draw("$\alpha$", arc(M, A, B, 0.25 * r, CW), heavygreen);
// draw angle at C2
draw(C2--A, blue);
draw(C2--B, blue);
draw("$\varphi$", arc(C2, B, A, 0.25 * r, CW), blue);
//draw(shift(2,0) * Label("$\varphi$", Relative(0.2)), arc(C2, A, B, 0.1 * r), blue);
// draw angle at C1
draw(C1--A, blue);
draw(C1--B, blue);
draw(Label("$\varphi$", UnFill), arc(C1, B, A, 0.25 * r, CW), blue);
//draw("$\varphi$", arc(C1, A, B, 0.1 * r), blue);
// draw angle at C3
draw(C3--A, magenta);
draw(C3--B, magenta);
draw("$\psi$", arc(C3, A, B, 0.35 * r, CW), magenta);
// draw angle at C4
draw(C4--A, magenta);
draw(C4--B, magenta);
draw("$\psi$", arc(C4, A, B, 0.35 * r, CW), magenta);
dot(M); label("$M$", M, W); // draw center M
dot(A); label("$A$", A, dir(angleA)); // draw point A
dot(B); label("$B$", B, dir(angleB)); // draw point B
dot(C1); label("$C_1$", C1, dir(angleC1)); // draw point C1
dot(C2); label("$C_2$", C2, dir(angleC2)); // draw point C2
dot(C3); label("$C_3$", C3, dir(angleC3)); // draw point C3
dot(C4); label("$C_4$", C4, dir(angleC4)); // draw point C4
draw(Label("$b_1$", Center, UnFill), arc(M, 1.15 * r, 60, 90), heavygreen, Arrows); // label arc b1
draw(Label("$b_2$", Center, UnFill), arc(M, 1.15 * r, 125, 160), Arrows); // label arc b2
|
Licensing[edit]
This file is made available under the Creative Commons CC0 1.0 Universal Public Domain Dedication. | |
The person who associated a work with this deed has dedicated the work to the public domain by waiving all of their rights to the work worldwide under copyright law, including all related and neighboring rights, to the extent allowed by law. You can copy, modify, distribute and perform the work, even for commercial purposes, all without asking permission.
http://creativecommons.org/publicdomain/zero/1.0/deed.enCC0Creative Commons Zero, Public Domain Dedicationfalsefalse |
File history
Click on a date/time to view the file as it appeared at that time.
Date/Time | Thumbnail | Dimensions | User | Comment | |
---|---|---|---|---|---|
current | 08:07, 10 November 2020 | 219 × 198 (28 KB) | SweetWood (talk | contribs) | added label for chord | |
12:44, 9 November 2020 | 219 × 198 (27 KB) | SweetWood (talk | contribs) | Uploaded own work with UploadWizard |
You cannot overwrite this file.
File usage on Commons
The following page uses this file:
File usage on other wikis
The following other wikis use this file:
- Usage on de.wikipedia.org
Metadata
This file contains additional information such as Exif metadata which may have been added by the digital camera, scanner, or software program used to create or digitize it. If the file has been modified from its original state, some details such as the timestamp may not fully reflect those of the original file. The timestamp is only as accurate as the clock in the camera, and it may be completely wrong.
Width | 175pt |
---|---|
Height | 158.21pt |